<html>
<Title>Excel Spreadsheet Component</Title>
<body>
<br/>
<br/>
<object classid="clsid:0002E551-0000-0000-C000-000000000046" 
   id="Spread1" width=600 height=300>
</object>
<br/>
<br/>
<button id="btnRename">Rename this sheet</button>
<button id="btnFill">Fill with data</button>
<button id="btnSave">Save to Excel</button>

<SCRIPT LANGUAGE="VBScript">

Dim intNum	' global variable

Sub btnRename_OnClick()
	Dim curSh  ' ActiveSheet
	 
	set curSh = Spread1.ActiveSheet

	Alert "Spreadsheet Web Component contains: " & vbCrLf _
		& curSh.rows.count & " rows" & vbCrLf _
		& curSh.columns.count & " columns "

	 If curSh.UsedRange.Address = "$A$1" and _ 
		curSh.Cells(1,1).value = "" then 
	         Alert "No data in this sheet."
	 Else
		intNum = intNum + 1
		curSh.name = "My Data" & intNum
	 End if
End Sub

Sub btnFill_OnClick()
	Dim conn		
	Dim rst		
	Dim strSQL
	Dim count
	Dim r
	Dim c
	Dim myData

	' establish connection to the database
	 conn="Provider=Microsoft.Jet.OleDB.4.0; Data Source=" & _
	   "C:\Program Files\Microsoft Office\Office11\" & _ 
	   "Samples\Northwind.mdb"

	' Create a Recordset
	 Set rst = CreateObject("ADODB.Recordset")
	 
	' select all records from Order Details table
	 strSql = "SELECT * FROM [Order Details]" 

	' Open a static (3) Recordset (and execute the SQL 
	' statement above) using the open connection
	 rst.Open strSql, conn, 3 

	' enter field names as column headings
	 For count = 0 to rst.fields.count - 1
	       r = r + 1
	       With Spread1.ActiveSheet.Cells(1, r)
	          .Value = rst.Fields(count).Name
	          .Font.Bold = True
	       End with
	 Next

	' get data from the Recordset into a variable
	' data is stored as a two-demensional array
	 myData = rst.GetRows()
	 
	 'get the number of returned rows
	 returnedRows = UBound(mydata, 2) + 1

	' enter data into worksheet cells
	 For r = 1 to returnedRows
		For c = 1 to rst.Fields.Count
		  Spread1.ActiveSheet.Cells(r+1, c).value = _ 
			 myData(c-1, r-1)
		Next
	 Next
	 
	 ' close the Recordset
	 rst.close
	 set rst = Nothing
End Sub

Sub btnSave_OnClick()
	Dim strFileName
	Dim fso
	Dim txtStream
	Dim strData

	strFileName="C:\ExcelWithOWC\myDataBook.xls"
	set fso = CreateObject("Scripting.FileSystemObject")
	set txtStream = fso.CreateTextFile(strFileName)
	Spread1.DataType="HTMLData"
	strData = Spread1.HTMLData
	txtStream.WriteLine strData
	txtStream.Close
	set txtStream = Nothing
	Set fso = Nothing
	MsgBox "Your spreadsheet data was saved in " & _ 
	              strFileName & " file."
End Sub

</SCRIPT>
</body>
</html>